# Maintainer: Jeremy Anderson <noreply@dcos.net>
pkgname=nirc-rs
pkgver=0.8.1
pkgrel=1
pkgdesc="Sovereign Data Terminal — multi-protocol terminal chat client (IRC, Matrix, ADC/DC++, Revolt, BitChat P2P)"
arch=('x86_64' 'aarch64')
url="https://git.dcos.net/dcosnet/nirc-rs"
license=('GPL-3.0-or-later')
depends=('gcc-libs' 'openssl')
makedepends=('cargo')
optdepends=('torsocks: Tor routing' 'proxychains-ng: proxy routing')
conflicts=('nirc')
provides=('nirc')
source=("${pkgname}-${pkgver}.tar.gz::https://git.dcos.net/dcosnet/nirc-rs/archive/v${pkgver}.tar.gz")
sha256sums=('SKIP')

prepare() {
    cd "${pkgname}-${pkgver}"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "${pkgname}-${pkgver}"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --frozen --release
}

check() {
    cd "${pkgname}-${pkgver}"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo test --frozen --release
}

package() {
    cd "${pkgname}-${pkgver}"
    install -Dm755 target/release/nirc "${pkgdir}/usr/bin/nirc"
    install -Dm644 man/man1/nirc.1 "${pkgdir}/usr/share/man/man1/nirc.1"
    install -Dm644 completions/nirc.bash "${pkgdir}/usr/share/bash-completion/completions/nirc"
    install -Dm644 completions/nirc.zsh "${pkgdir}/usr/share/zsh/site-functions/_nirc"
    install -Dm644 completions/nirc.fish "${pkgdir}/usr/share/fish/vendor_completions.d/nirc.fish"
    gzip -9 "${pkgdir}/usr/share/man/man1/nirc.1"
}